f1 {
fractal:
  title="f1" width=640 height=480 numlayers=1
layer:
  caption="Layer 1" visible=yes alpha=no
mapping:
  center=-0.79609375/0.15 magn=91.4285714285714286 angle=0
formula:
  filename="Standard.ufm" entry="FastMandel" maxiter=251 percheck=normal
  p_Start=0/0 p_Bailout=128
inside:
  filename="lp.ucl" entry="EpsilonCross" transfer=linear repeat=yes
  p_xcolour=0.2 p_xdis=0.01 p_ycolour=0.6 p_ydis=0.01 p_colourf=0.1
  p_center=0/0 p_angle=0 p_skip=yes
outside:
  filename="dmj.ucl" entry="dmj-Smooth" transfer=linear repeat=yes
  p_power=2/0 p_bailout=128
gradient:
  smooth=yes numnodes=4 index=0 color=8716288 index=100 color=16121855
  index=200 color=51967 index=300 color=144
}

lp.ucl:EpsilonCross(BOTH) {
init:
  int count = 0
  int col = 0
  float col2 = 0
  complex z2 = 0
  complex ang = exp(flip(-@angle*pi/180))
  
loop:
  count = count + 1
  z2 = (#z - @center)*ang
  
  IF (@skip==false) || (count > 1)
    IF (col == 0)
      IF (real(abs(real(z2))) < @xdis )
        col = 1
        col2 = real(z2)
      ENDIF
  
      IF (real(abs(imag(z2))) < @ydis )
        col = 2
        col2 = imag(z2)
      ENDIF   
    ENDIF
  ENDIF
  
final:
  IF (col == 0)
    #solid = true
  ELSEIF (col == 1)
    #index = @xcolour + @colourf * col2 / @xdis
    ; divide by @xdis to make thinner stripes have same gradient
     
  ELSEIF (col == 2)
    #index = @ycolour + @colourf * col2 / @ydis
  ENDIF
  
  
default:
  title = "Fractint Epsilon Cross"
  
  param xcolour
    caption = "X-axis colour offset"
    default = 0.2
    hint = "determines what index number to colour \
    an orbit which come near to x-axis"
  endparam
  
  param xdis
    caption = "X-axis distance"
    default = 0.01
    hint = "determines how close to the x-axis \
    an orbit has to come to be caught"
  endparam 

  param ycolour
    caption = "Y-axis colour offset"
    default = 0.6
    hint = "determines what index number to colour \
    an orbit which come near to y-axis"
  endparam
  
  param ydis
    caption = "Y-axis distance"
    default = 0.01
    hint = "determines how close to the y-axis \
    an orbit has to come to be caught"
  endparam
  
  param colourf
    caption = "Internal colour factor"
    default = 0.1
    hint = "strength of colouring within bands"
  endparam

  param center
    caption = "Center"
    default = (0.0,0.0)
    hint = "0,0 is standard epsilon cross colouring"
  endparam
  
  param angle
    caption  = "Tilt angle"
    default = 0.0
    hint = "Angle in degrees through which \
    the axes are rotated"
  endparam
 
  param skip
    caption = "Skip first iteration?"
    default = true
    hint = "Check to ignore the first iteration"
  endparam


}

dmj.ucl:dmj-Smooth(OUTSIDE) {
;
; This coloring method provides smooth iteration
; colors for Mandelbrot and other z^2 formula types
; (Phoenix, Julia).  Results on other types may be
; unpredictable, but might be interesting.
;
; Thanks to F. Slijkerman for some tweaks.
; Thanks to Linas Vepstas for the math.
;
init:
  complex il = 1/log(@power)    ; Inverse log (power).
  float lp = log(log(@bailout))    ; log(log bailout).

final:
  #index = 0.05 * real(#numiter + il*lp - il*log(log(cabs(#z))))

default:
  title = "Smoothed Iterations (Mandelbrot)"

  param power
    caption = "Exponent"
    default = (2,0)
    hint = "This should be set to match the exponent of the \
            formula you are using.  For Mandelbrot, this is 2."
  endparam
  param bailout
    caption = "Bailout value"
    default = 128.0
    min = 1
    hint = "This should be set to match the bailout value in \
            the Formula tab."
  endparam
}